You cannot select more than 25 topics
Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
283 lines
8.1 KiB
Bash
283 lines
8.1 KiB
Bash
# vim:ft=zsh ts=2 sw=2 sts=2
|
|
#
|
|
# powerlevel9k Theme
|
|
# https://github.com/bhilburn/oh-my-zsh/blob/master/themes/powerlevel9k.zsh-theme
|
|
#
|
|
# This theme is based off of agnoster's Theme:
|
|
# https://gist.github.com/3712874
|
|
#
|
|
# In order for this theme to render correctly, you will need a
|
|
# [Powerline-patched font](https://github.com/Lokaltog/powerline-fonts).
|
|
#
|
|
|
|
setopt prompt_subst
|
|
autoload -Uz vcs_info
|
|
zstyle ':vcs_info:*' stagedstr '✚'
|
|
zstyle ':vcs_info:git:*' unstagedstr '●'
|
|
zstyle ':vcs_info:git*' actionformats " %b %F{red}| %a%f"
|
|
zstyle ':vcs_info:git*' formats " %b %c%u%m"
|
|
zstyle ':vcs_info:*' check-for-changes true
|
|
zstyle ':vcs_info:git*+set-message:*' hooks git-untracked git-aheadbehind git-remotebranch git-tagname
|
|
zstyle ':vcs_info:*' enable git
|
|
|
|
### Segment drawing
|
|
# A few utility functions to make it easy and re-usable to draw segmented prompts
|
|
|
|
# The `CURRENT_BG` variable is used to remember what the last BG color used was
|
|
# when building the left-hand prompt. Because the RPROMPT is created from
|
|
# right-left but reads the opposite, this isn't necessary for the other side.
|
|
CURRENT_BG='NONE'
|
|
|
|
# These characters require the Powerline fonts to work properly. If see boxes or
|
|
# bizarre characters below, your fonts are not correctly installed.
|
|
LEFT_SEGMENT_SEPARATOR=''
|
|
RIGHT_SEGMENT_SEPARATOR=''
|
|
|
|
################################################################
|
|
# Prompt Segment Constructors
|
|
################################################################
|
|
|
|
# Begin a left prompt segment
|
|
# Takes two arguments, background and foreground. Both can be omitted,
|
|
# rendering default background/foreground.
|
|
left_prompt_segment() {
|
|
local bg fg
|
|
[[ -n $1 ]] && bg="%K{$1}" || bg="%k"
|
|
[[ -n $2 ]] && fg="%F{$2}" || fg="%f"
|
|
if [[ $CURRENT_BG != 'NONE' && $1 != $CURRENT_BG ]]; then
|
|
echo -n " %{$bg%F{$CURRENT_BG}%}$LEFT_SEGMENT_SEPARATOR%{$fg%} "
|
|
else
|
|
echo -n "%{$bg%}%{$fg%} "
|
|
fi
|
|
CURRENT_BG=$1
|
|
[[ -n $3 ]] && echo -n $3
|
|
}
|
|
|
|
# End the left prompt, closing any open segments
|
|
left_prompt_end() {
|
|
if [[ -n $CURRENT_BG ]]; then
|
|
echo -n " %{%k%F{$CURRENT_BG}%}$LEFT_SEGMENT_SEPARATOR"
|
|
else
|
|
echo -n "%{%k%}"
|
|
fi
|
|
echo -n "%{%f%}"
|
|
CURRENT_BG=''
|
|
}
|
|
|
|
# Begin a right prompt segment
|
|
# Takes two arguments, background and foreground. Both can be omitted,
|
|
# rendering default background/foreground. No ending for the right prompt
|
|
# segment is needed (unlike the left prompt, above).
|
|
right_prompt_segment() {
|
|
local bg fg
|
|
[[ -n $1 ]] && bg="%K{$1}" || bg="%k"
|
|
[[ -n $2 ]] && fg="%F{$2}" || fg="%f"
|
|
echo -n " %f%F{$1}$RIGHT_SEGMENT_SEPARATOR%f%{$bg%}%{$fg%} "
|
|
[[ -n $3 ]] && echo -n $3
|
|
}
|
|
|
|
################################################################
|
|
# Prompt Components
|
|
################################################################
|
|
|
|
# Context: user@hostname (who am I and where am I)
|
|
# Note that if $DEFAULT_USER is not set, this prompt segment will always print
|
|
prompt_context() {
|
|
if [[ "$USER" != "$DEFAULT_USER" || -n "$SSH_CLIENT" ]]; then
|
|
left_prompt_segment black default "%(!.%{%F{yellow}%}.)$USER@%m"
|
|
fi
|
|
}
|
|
|
|
# Git: branch/detached head, dirty status
|
|
prompt_git() {
|
|
local dirty
|
|
|
|
if $(git rev-parse --is-inside-work-tree >/dev/null 2>&1); then
|
|
dirty=$(parse_git_dirty)
|
|
if [[ -n $dirty ]]; then
|
|
left_prompt_segment yellow black
|
|
else
|
|
left_prompt_segment green black
|
|
fi
|
|
|
|
echo -n "${vcs_info_msg_0_}"
|
|
fi
|
|
}
|
|
|
|
function +vi-git-untracked() {
|
|
if [[ $(git rev-parse --is-inside-work-tree 2> /dev/null) == 'true' && \
|
|
$(git ls-files --others --exclude-standard | sed q | wc -l | tr -d ' ') != 0 ]]; then
|
|
hook_com[unstaged]+="%F{black}?%f"
|
|
fi
|
|
}
|
|
|
|
function +vi-git-aheadbehind() {
|
|
local ahead behind branch_name
|
|
local -a gitstatus
|
|
|
|
branch_name=${$(git symbolic-ref --short HEAD 2>/dev/null)}
|
|
|
|
# for git prior to 1.7
|
|
# ahead=$(git rev-list origin/${branch_name}..HEAD | wc -l)
|
|
ahead=$(git rev-list ${branch_name}@{upstream}..HEAD 2>/dev/null | wc -l | tr -d ' ')
|
|
(( $ahead )) && gitstatus+=( "%F{black}↑${ahead}%f" )
|
|
|
|
# for git prior to 1.7
|
|
# behind=$(git rev-list HEAD..origin/${branch_name} | wc -l)
|
|
behind=$(git rev-list HEAD..${branch_name}@{upstream} 2>/dev/null | wc -l | tr -d ' ')
|
|
(( $behind )) && gitstatus+=( "%F{black}↓${behind}%f" )
|
|
|
|
hook_com[misc]+=${(j::)gitstatus}
|
|
}
|
|
|
|
function +vi-git-remotebranch() {
|
|
local remote branch_name
|
|
|
|
# Are we on a remote-tracking branch?
|
|
remote=${$(git rev-parse --verify HEAD@{upstream} --symbolic-full-name 2>/dev/null)/refs\/(remotes|heads)\/}
|
|
branch_name=${$(git symbolic-ref --short HEAD 2>/dev/null)}
|
|
|
|
hook_com[branch]="%F{black}${hook_com[branch]}%f"
|
|
# Always show the remote
|
|
#if [[ -n ${remote} ]] ; then
|
|
# Only show the remote if it differs from the local
|
|
if [[ -n ${remote} && ${remote#*/} != ${branch_name} ]] ; then
|
|
hook_com[branch]+="%F{black}→%f%F{black}${remote}%f"
|
|
fi
|
|
}
|
|
|
|
function +vi-git-tagname() {
|
|
local tag
|
|
|
|
tag=$(git describe --tags --exact-match HEAD 2>/dev/null)
|
|
[[ -n ${tag} ]] && hook_com[branch]="%F{black}${tag}%f"
|
|
}
|
|
|
|
# Mercurial status
|
|
prompt_hg() {
|
|
local rev status
|
|
if $(hg id >/dev/null 2>&1); then
|
|
if $(hg prompt >/dev/null 2>&1); then
|
|
if [[ $(hg prompt "{status|unknown}") = "?" ]]; then
|
|
# if files are not added
|
|
left_prompt_segment red white
|
|
st='±'
|
|
elif [[ -n $(hg prompt "{status|modified}") ]]; then
|
|
# if any modification
|
|
left_prompt_segment yellow black
|
|
st='±'
|
|
else
|
|
# if working copy is clean
|
|
left_prompt_segment green black
|
|
fi
|
|
echo -n $(hg prompt "☿ {rev}@{branch}") $st
|
|
else
|
|
st=""
|
|
rev=$(hg id -n 2>/dev/null | sed 's/[^-0-9]//g')
|
|
branch=$(hg id -b 2>/dev/null)
|
|
if `hg st | grep -Eq "^\?"`; then
|
|
left_prompt_segment red black
|
|
st='±'
|
|
elif `hg st | grep -Eq "^(M|A)"`; then
|
|
left_prompt_segment yellow black
|
|
st='±'
|
|
else
|
|
left_prompt_segment green black
|
|
fi
|
|
echo -n "☿ $rev@$branch" $st
|
|
fi
|
|
fi
|
|
}
|
|
|
|
# Dir: current working directory
|
|
prompt_dir() {
|
|
left_prompt_segment blue black '%~'
|
|
}
|
|
|
|
# Virtualenv: current working virtualenv
|
|
# More information on virtualenv (Python):
|
|
# https://virtualenv.pypa.io/en/latest/virtualenv.html
|
|
prompt_virtualenv() {
|
|
local virtualenv_path="$VIRTUAL_ENV"
|
|
if [[ -n $virtualenv_path && -n $VIRTUAL_ENV_DISABLE_PROMPT ]]; then
|
|
left_prompt_segment blue black "(`basename $virtualenv_path`)"
|
|
fi
|
|
}
|
|
|
|
# Left Status: (return code, root status, background jobs)
|
|
# This creates a status segment for the *left* prompt
|
|
prompt_status() {
|
|
local symbols
|
|
symbols=()
|
|
[[ $RETVAL -ne 0 ]] && symbols+="%{%F{red}%}✘"
|
|
[[ $UID -eq 0 ]] && symbols+="%{%F{yellow}%}⚡"
|
|
[[ $(jobs -l | wc -l) -gt 0 ]] && symbols+="%{%F{cyan}%}⚙"
|
|
|
|
[[ -n "$symbols" ]] && left_prompt_segment black default "$symbols"
|
|
}
|
|
|
|
# Right Status: (return code, root status, background jobs)
|
|
# This creates a status segment for the *right* prompt. Exact same thing as
|
|
# above - just other side.
|
|
rprompt_status() {
|
|
local symbols bg
|
|
symbols=()
|
|
|
|
if [[ $RETVAL -ne 0 ]]; then
|
|
symbols+="%{%F{"226"}%}%? ↵"
|
|
bg="009"
|
|
else
|
|
symbols+="%{%F{"046"}%}✓"
|
|
bg="008"
|
|
fi
|
|
|
|
[[ $UID -eq 0 ]] && symbols+="%{%F{yellow}%}⚡"
|
|
[[ $(jobs -l | wc -l) -gt 0 ]] && symbols+="%{%F{cyan}%}⚙"
|
|
|
|
[[ -n "$symbols" ]] && right_prompt_segment $bg default "$symbols"
|
|
}
|
|
|
|
# System time
|
|
prompt_time() {
|
|
right_prompt_segment white black '%D{%H:%M:%S} '
|
|
}
|
|
|
|
# Command number (in local history)
|
|
prompt_history() {
|
|
right_prompt_segment "244" black '%h'
|
|
}
|
|
|
|
# Ruby Version Manager information
|
|
prompt_rvm() {
|
|
local rvm_prompt
|
|
rvm_prompt=`rvm-prompt`
|
|
if [ "$rvm_prompt" != "" ]; then
|
|
left_prompt_segment "240" white "$rvm_prompt "
|
|
fi
|
|
}
|
|
|
|
# Main prompt
|
|
build_left_prompt() {
|
|
#prompt_virtualenv
|
|
prompt_context
|
|
prompt_dir
|
|
prompt_git
|
|
#prompt_hg
|
|
#prompt_rvm
|
|
left_prompt_end
|
|
}
|
|
|
|
# Right prompt
|
|
build_right_prompt() {
|
|
RETVAL=$?
|
|
rprompt_status
|
|
prompt_history
|
|
prompt_time
|
|
}
|
|
|
|
# Create the prompts
|
|
precmd() { vcs_info }
|
|
|
|
PROMPT='%{%f%b%k%}$(build_left_prompt) '
|
|
RPROMPT='%{%f%b%k%}$(build_right_prompt)%{$reset_color%}'
|